home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ShareWare OnLine 2
/
ShareWare OnLine Volume 2 (CMS Software)(1993).iso
/
games2
/
twast11.zip
/
TWASTMAC.ZIP
/
TWASSIST.SCR
< prev
next >
Wrap
Text File
|
1993-02-06
|
4KB
|
178 lines
; TWASSIST.SCR (QModem v4.3 script to display the information that can be
; used by TWASSIST)
;
; 02/06/93 - Albin Gersich
;
String TWASSIST DATADIR
Assign TWASSIST "c:\tw\twassist.exe" ; PATH TO TWASSIST EXECUTABLE
Assign DATADIR "c:\tw" ; DIRECTORY WHERE DATA FILES ARE
GetScr ; SAVE SCREEN FOR RESTORATION LATER
Graphics ANSI
TurnON 8_BIT
TurnOFF LINEFEED
TurnON XON/XOFF
TurnON NOISE
TurnOFF MUSIC
TurnON SCROLL
TurnOFF PRINT
TurnOFF ECHO
TurnOFF SPLIT
TurnOFF BS_DEL
TurnON STATUSLN
TurnOFF DOORWAY
TimeOut 200 ; Set Waitfor for 200 seconds
String DO_VGS DO_FIGHTERS DO_MINES DO_AVOIDS DO_SECTORS DO_PORTS
Assign DO_VGS FALSE
Assign DO_FIGHTERS FALSE
Assign DO_MINES FALSE
Assign DO_AVOIDS FALSE
Assign DO_SECTORS FALSE
Assign DO_PORTS FALSE
;
; CREATE A WINDOW TO PROMPT THE USER FOR
; WHICH REPORTS THEY WANT TO CAPTURE
;
String KEY
Box 10 5 70 20
ClrScr
GoToXY 2 2
Display "(T)W2002 Assistant"
GoToXY 2 4
Display "(A)ll reports"
GoToXY 2 5
Display "(C)IM sector and port reports"
GoToXY 2 6
Display "(P)ort report"
GoToXY 2 7
Display "(F)ighters, mines, and avoids"
GoToXY 2 9
Display "E(x)it script"
GET_SELECTION:
GoToXY 2 11
Display "Your selection? "
GetN KEY 1
If "$KEY" = "T" RUN_TWASSIST
If "$KEY" <> "A" NOT_A
Assign DO_VGS TRUE
Assign DO_FIGHTERS TRUE
Assign DO_MINES TRUE
Assign DO_AVOIDS TRUE
Assign DO_SECTORS TRUE
Assign DO_PORTS TRUE
GoTo DO_CAPTURE
NOT_A:
If "$KEY" <> "C" NOT_C
Assign DO_SECTORS TRUE
Assign DO_PORTS TRUE
GoTo DO_CAPTURE
NOT_C:
If "$KEY" <> "P" NOT_P
Assign DO_PORTS TRUE
GoTo DO_CAPTURE
NOT_P:
If "$KEY" <> "F" NOT_F
Assign DO_FIGHTERS TRUE
Assign DO_MINES TRUE
Assign DO_AVOIDS TRUE
GoTo DO_CAPTURE
NOT_F:
If "$KEY" <> "X" NOT_X
;Window 1 1 80 24 ; RESTORE TO FULL WINDOW
PutScr ; RESTORE ORIGINAL SCREEN
Exit
NOT_X:
GoTo GET_SELECTION
;
; RUN TWASSIST
;
RUN_TWASSIST:
;Window 1 1 80 24 ; RESTORE TO FULL WINDOW
;ClrScr
PutScr ; RESTORE ORIGINAL SCREEN
;String DIR
;Assign DIR ; ORIGINAL DIRECTORY
CHDIR $DATADIR
BigDOS "$TWASSIST"
;CHDIR DIR ; RESTORE ORIGINAL DIRECTORY
Exit
;
; CAPTURE TW REPORTS
;
DO_CAPTURE:
;Window 1 1 80 24 ; RESTORE TO FULL WINDOW
;ClrScr
PutScr ; RESTORE ORIGINAL SCREEN
;
; VIEW GAME STATUS
;
If $DO_VGS = FALSE SKIP_VGS
Send "V"
Waitfor "Command"
SKIP_VGS:
;
; DEPLOYED FIGHTER SCAN
;
If $DO_FIGHTERS = FALSE SKIP_FIGHTERS
Send "G"
Waitfor "Command"
SKIP_FIGHTERS:
;
; DEPLOYED MINE SCAN
;
If $DO_MINES = FALSE SKIP_MINES
Send "K"
Waitfor "Command"
SKIP_MINES:
;
; ENGAGE GAME COMPUTER
;
Send "C"
Waitfor "Computer command"
;
; LIST CURRENT AVOIDS
;
If $DO_AVOIDS = FALSE SKIP_AVOIDS
Send "X"
Waitfor "Computer command"
SKIP_AVOIDS:
;
; COMPUTER INTERROGATION MODE (CIM)
;
Send "╚╔╩╦╠═"
Waitfor ":"
;
; CIM SECTOR REPORT
;
If $DO_SECTORS = FALSE SKIP_SECTORS
Send "I"
Waitfor ":"
SKIP_SECTORS:
;
; CIM PORT REPORT
;
If $DO_PORTS = FALSE SKIP_PORTS
Send "R"
Waitfor ":"
SKIP_PORTS:
;
; QUIT CIM
;
Send "Q"
Waitfor "Computer command"
;
; QUIT GAME COMPUTER
;
Send "Q"
Waitfor "Command"
;
; WE ARE BACK TO THE MAIN PROMPT
; AND THE END OF THIS MACRO
;
Exit